Allow users to set path styles

marker.nix

@@ -1,27 +1,128 @@
 { lib, config, ... }:
 let
+  # Returns the uppercased first label or number of a string
+  firstUpperAlnum =
+    str:
+      lib.mapNullable
+        lib.head (builtins.match "[^A-Z0-9]*([A-Z0-9]).*" (lib.toUpper str));
+
+  userType = lib.types.submodule (
+    { name, ... }: {
+      options = {
+        departure = lib.mkOption {
+          type = markerType;
+          default = {};
+        };
+
+        arrival = lib.mkOption {
+          type = markerType;
+          default = {};
+        };
+      };
+
+      config = {
+        departure.style.label = lib.mkDefault (firstUpperAlnum name);
+        arrival.style.label = lib.mkDefault (firstUpperAlnum name);
+      };
+    });
+
   markerType = lib.types.submodule {
     options = {
       location = lib.mkOption {
         type = lib.types.nullOr lib.types.str;
         default = null;
       };
+
+      style = {
+        label = lib.mkOption {
+          type = lib.types.nullOr
+            (lib.types.strMatching "[0-9A-Z]");
+          default = null;
+        };
+
+        color = lib.mkOption {
+          type = colorType;
+          default = "red";
+        };
+
+        size = lib.mkOption {
+          type = lib.types.enum [
+            "tiny"
+            "small"
+            "medium"
+            "large"
+          ];
+
+          default = "medium";
         };
       };
+    };
+  };
+
+  colorType = lib.types.either
+    (lib.types.strMatching "0x[0-9A-F]{3}[0-9A-F]{3}?")
+    (lib.types.enum [
+      "black"
+      "blue"
+      "brown"
+      "gray"
+      "green"
+      "orange"
+      "purple"
+      "red"
+      "white"
+      "yellow"
+    ]);
 in
 {
+  imports = [
+    ./path.nix
+  ];
+
   options = {
+    users = lib.mkOption {
+      type = lib.types.attrsOf userType;
+    };
+
     map.markers = lib.mkOption {
       type = lib.types.listOf markerType;
     };
   };
 
   config = {
+    users = {
+      manuel = {
+        departure = {
+          location = "Switzerland";
+          style.size = "small";
+        };
+
+        arrival = {
+          location = "Prague";
+        };
+
+        pathStyle = {
+          weight = 10;
+        };
+      };
+
+      ganondorf.departure =  {
+        location = "Argentinia";
+
+        style = {
+          color = "green";
+        };
+      };
+    };
+
     map = {
-      markers = [
+      markers = lib.filter
-        { location = "Switzerland"; }
+        (marker: marker.location != null)
-        { location = "New York"; }
+        (
-      ];
+          lib.concatMap (user: [
+            user.departure
+            user.arrival
+          ]) (lib.attrValues config.users));
 
       center = lib.mkIf
         (lib.length config.map.markers >= 1)
@@ -34,12 +135,30 @@ in
 
     requestParams =
       let
-        paramsForMarkers = builtins.map
+        paramForMarker =
-          (marker: "$(${config.scripts.geocode}/bin/geocode ${
+          marker:
-            lib.escapeShellArg marker.location})")
+            let
-          config.map.markers;
+              size = {
-      in [
+                tiny = "tiny";
-        "markers=\"${lib.concatStringsSep "|" paramsForMarkers}\""
+                small = "small";
+                medium = "mid";
+                large = null;
+              }.${marker.style.size};
+              attributes =
+                lib.optional
+                  (marker.style.label != null)
+                  "label:${marker.style.label}"
+                ++ lib.optional
+                  (size != null)
+                  "size:${size}"
+                ++ [
+                  "color:${marker.style.color}"
+                  "$(${config.scripts.geocode}/bin/geocode ${
+                    lib.escapeShellArg marker.location
+                  })"
                 ];
+            in
+              "markers=\"${lib.concatStringsSep "|" attributes}\"";
+      in builtins.map paramForMarker config.map.markers;
   };
 }

path.nix

@@ -0,0 +1,74 @@
+{ lib, config, ... }:
+let
+  pathType = lib.types.submodule {
+    options = {
+      locations = lib.mkOption {
+        type = lib.types.listOf lib.types.str;
+      };
+
+      style = lib.mkOption {
+        type = pathStyleType;
+        default = {};
+      };
+    };
+  };
+
+  pathStyleType = lib.types.submodule {
+    options = {
+      weight = lib.mkOption {
+        type = lib.types.ints.between 1 20;
+        default = 5;
+      };
+    };
+  };
+in
+{
+  options = {
+    users = lib.mkOption {
+      type = lib.types.attrsOf (
+        lib.types.submodule {
+          options.pathStyle = lib.mkOption {
+            type = pathStyleType;
+            default = {};
+          };
+        });
+    };
+
+    map.paths = lib.mkOption {
+      type = lib.types.listOf pathType;
+    };
+  };
+
+  config = {
+    map.paths = builtins.map (
+      user: {
+        locations = [
+          user.departure.location
+          user.arrival.location
+        ];
+
+        style = user.pathStyle;
+      }) (lib.filter (
+        user:
+          user.departure.location != null
+          && user.arrival.location != null
+      ) (lib.attrValues config.users));
+
+    requestParams =
+      let
+        attrForLocation =
+          loc: "$(${config.scripts.geocode}/bin/geocode ${lib.escapeShellArg loc})";
+        paramForPath =
+          path:
+            let
+              attributes =
+                [
+                  "weight:${toString path.style.weight}"
+                ]
+                ++ builtins.map attrForLocation path.locations;
+            in
+              ''path="${lib.concatStringsSep "|" attributes}"'';
+      in
+        builtins.map paramForPath config.map.paths;
+  };
+}