PortValhalla/scripts/Arch/OS/setup.fish

#!/bin/env fish
begin
    set -l dir (status dirname)
    source "$dir/../../Common/Scripts/config.fish"
    source "$dir/../../Common/Scripts/hooks.fish"

    set -q CONFIG_MODULE || set -l CONFIG_MODULE "$dir/config.nix"

    set -l mountDir (getConfig valhalla.partition.rootDir)

    set -q USER_NAME || set -l USER_NAME manuel
    set -q USER_DISPLAYNAME
    set -q USER_GROUPS || set -l USER_GROUPS ""
    begin
        set -l projectRoot (realpath "$dir/../../..")
        set -l projectName (basename "$projectRoot")
        set -l relativeDir (realpath --relative-to "$projectRoot" "$dir")
        set -l tempRoot "/opt/$(basename "$projectName")"
        set -l tempDir "$tempRoot/$relativeDir"

        if set -l keyMap (getConfig valhalla.keyMap)
            loadkeys "$keyMap"
        end

        and if set -l timezone (getConfig valhalla.timeZone)
            timedatectl set-timezone "$timezone"
        end

        and CONFIG_MODULE=$CONFIG_MODULE bash "$dir/../../Common/OS/partition.sh"

        and pacman-key --init
        and pacman-key --populate

        and pacstrap -K "$mountDir" \
            base \
            linux \
            linux-firmware \
            networkmanager \
            man-db \
            man-pages \
            texinfo

        and runHook installDrivers "Installing drivers…" || true

        and "$dir/../../copy-repo.fish" "$mountDir$tempRoot"
        and genfstab -U "$mountDir" >> "$mountDir/etc/fstab"

        and arch-chroot "$mountDir" systemctl enable NetworkManager

        and if set -q timezone
            arch-chroot "$mountDir" ln -sf "/usr/share/zoneinfo/$timezone" /etc/localtime
        end

        and arch-chroot "$mountDir" hwclock --systohc

        and begin
            getConfig valhalla.i18n.localeSettings --json | \
                jq --raw-output '[.[] | split(".") | .[0]] | unique | join("\\\\|")'
        end | begin
            read LOCALES
            and arch-chroot "$mountDir" sed -i "s/^#\?\(\($LOCALES\).*\)\$/\1/" /etc/locale.gen
        end

        and begin
            getConfig valhalla.i18n.localeSettings --json | \
                jq --raw-output '[keys[] as $key | "\($key)=\(.[$key])"] | join("\n")'
        end | arch-chroot "$mountDir" tee /etc/locale.conf > /dev/null

        and if set -q keyMap
            echo "KEYMAP=$keyMap" | arch-chroot "$mountDir" tee /etc/vconsole.conf > /dev/null
        end

        and echo "$ARCH_HOSTNAME" | arch-chroot "$mountDir" tee /etc/hostname > /dev/null

        and arch-chroot "$mountDir" mkinitcpio -P
        and arch-chroot "$mountDir" bash "$tempDir/../Software/GRUB/install.sh"
        and arch-chroot "$mountDir" bash "$tempDir/../Software/sudo/install.sh"
        and pacstrap -K "$mountDir" git

        and USER_NAME="$USER_NAME" \
        USER_DISPLAYNAME="$USER_DISPLAYNAME" \
        USER_GROUPS="$USER_GROUPS" \
            arch-chroot "$mountDir" bash "$tempDir/user.sh"

        and if set -l keyLayout (getConfig valhalla.keyboardLayout)
            set -l serviceName set-keymap.service
            and set -l serviceFile "$mountDir/etc/systemd/system/$serviceName"
            and cp "$dir/$serviceName" "$serviceFile"
            and systemd-nspawn -D "$mountDir" systemctl enable "$serviceName"
            and systemd-nspawn -bD "$mountDir" -E "ARCH_X11_KEYMAP=$keyLayout"
            and systemd-nspawn -D "$mountDir" systemctl disable "$serviceName"
            and rm "$serviceFile"
        end
    end
end