#!/bin/env fish
set -l dir (status dirname)
source "$dir/../Scripts/config.fish"
source "$dir/../Scripts/hooks.fish"

function copyNixConfig -V dir
    set -l configFile ~/.config/nix/nix.conf
    mkdir -p (dirname "$configFile")
    cp "$dir/../../../archiso/airootfs/root/.config/nix/nix.conf" "$configFile"
end

if [ (id -u) -eq 0 ]
    copyNixConfig
    set -l name (getConfig valhalla.setupUser.name)
    set -l sudoConfig "/etc/sudoers.d/PortValhalla"

    runHook createUser || \
        begin
            useradd \
                --comment "PortValhalla setup user" \
                --system \
                --no-user-group \
                --groups wheel,nix-users \
                --create-home \
                --uid (getConfig valhalla.setupUser.id --json) \
                "$name"
        end

    and begin
        echo "$name ALL=(ALL:ALL) NOPASSWD: ALL"
    end > "$sudoConfig"
    
    and sudo --preserve-env="CONFIG_MODULE" --user "$name" "$INSTALLER_SCRIPT"
    rm "$sudoConfig"
    userdel -r "$name"
else
    copyNixConfig
    source "$dir/../Software/bash/main.fish"
    runHook initialize || true
    runHook installDrivers || true
    runHook installOS || true
    runHook installSoftware || true
    runHook initializeConfig || true
    runHook postInstall || true
end