#!/bin/env fish
function chooseDisk -a outFile message

    while true
        set -l disks

        lsblk -do NAME,SIZE,TYPE | while read disk
            set -l diskInfo (string split -n " " $disk)

            if contains "$diskInfo[3]" "TYPE" "disk"
                set -a disks "$diskInfo"
            end
        end

        set -l diskCount (count $disks)
        set -l padding (math (string length "$diskCount") + 1)

        if [ "$diskCount" -gt 0 ]
            echo "$message"
            set -l prefix

            for i in (seq "$diskCount")
                if [ "$i" -eq 1 ]
                    set prefix ""
                else
                    set prefix "$(math "$i" - 1):"
                end

                printf "%"$padding"s %s\n" "$prefix" "$disks[$i]"
            end

            read -lP "Your choice: " choice
            or exit 1

            if math "0+$choice" &> /dev/null
                if [ "$choice" -ge 1 ] && [ "$choice" -le "$diskCount" ]
                    set -l disk (string split -n " " "$disks[$(math "$choice" + 1)]")
                    echo "/dev/$disk[1]" > $outFile
                    return
                end
            end

            echo "The specified choice \"$choice\" is invalid!"
        else
            echo "No valid disk found!" >&2
        end
    end

    return 1
end

chooseDisk $argv