#!/bin/env fish
begin
    set -l dir (status dirname)
    set -l root /usr/local/lib
    set -l secretsFile "docker-compose.secrets.yml"
    set -l nginxRoot "/etc/nginx/conf.d"
    set -l portPattern "^\([.[:digit:]]\+:\)\([[:digit:]]\+\)\(:[[:digit:]]\+\)"
    source "$dir/../../../../lib/software.fish"

    function getServiceName
        argparse -i "name=" -- $argv
        echo "$_flag_name"
    end

    function getServiceRoot -V root
        echo "$root/$(getServiceName $argv)"
    end

    function __getServiceNginxConfig -V nginxRoot
        echo "$nginxRoot/$(getServiceName $argv).conf"
    end

    function getServiceSecretsConfig -V secretsFile
        echo "$(getServiceRoot $argv)/$secretsFile"
    end

    function __getServicePortKey -V secretsFile -a name
        echo ".services.$name.ports[0]"
    end

    function installDockerService -V dir -V nginxRoot -V portPattern
        set -l services (getServiceConfigs $argv | string split0)
        sudo cp (getServiceNginxConfigSource $argv) (__getServiceNginxConfig $argv)

        for i in (seq 1 2 (count $services))
            set -l file (mktemp)
            set -l config (getServiceSecretsConfig $argv)
            set -l service $services[$i]
            set -l port (random 49152 65535)
            set -l portKey (__getServicePortKey "$service")
            set -l exposedPort
            sudo mkdir -p (getServiceRoot $argv)
            sudo mkdir -p "$nginxRoot"
            cp "$config" "$file"
            set exposedPort (yq --raw-output "$portKey" "$file" | sed "s/$portPattern/\1$port\3/")
            PORT=$exposedPort yq -y "$portKey = env.PORT" "$file" | sudo tee "$config" >/dev/null
        end
    end

    function configureDockerService -V portPattern
        set -l services (getServiceConfigs $argv | string split0)

        for i in (seq 1 2 (count $services))
            set -l config (getServiceSecretsConfig $argv)
            set -l service $services[$i]
            set -l location $services[(math $i + 1)]
            set -l portKey (__getServicePortKey "$service")
            set -l port (yq --raw-output "$portKey" "$config" | sed "s/$portPattern/\2/")
            set -l nginxConfig (__getServiceNginxConfig $argv)

            cat "$nginxConfig" | sed \
                -e "\;location $location {;,/}/{" \
                -e "s/\(proxy_pass \)\(.\+:\)\?[[:digit:]]\+\(;\)/\1\2$port\3/;" \
                -e "}" | sudo tee "$nginxConfig" >/dev/null
        end

        sudo systemctl restart nginx
    end

    function getBackupArgs -V root
        printf "%s\n" --hidden --no-ignore . --exclude "docker-compose.yml" "$root"
    end
end