#!/bin/env fish
begin
    set -l dir (status dirname)

    set -q CONFIG_MODULE || set -l CONFIG_MODULE "$dir/config.nix"
    set -q ARCH_TIMEZONE || set -l ARCH_TIMEZONE "Europe/Zurich"
    set -q ARCH_MOUNT_ROOT || set -l ARCH_MOUNT_ROOT ("$dir/../../eval-module.sh" "$CONFIG_MODULE" partition.rootDir --raw)
    set -q ARCH_LANG || set -l ARCH_LANG en_US.UTF-8
    set -q ARCH_KEYMAP || set -l ARCH_KEYMAP de_CH-latin1
    set -q ARCH_X11_KEYMAP || set -l ARCH_X11_KEYMAP ch
    set -q LOCALE_PATTERN || set -l LOCALE_PATTERN "\(de_CH\|en_US\)"

    set -q USER_NAME || set -l USER_NAME manuel
    set -q USER_DISPLAYNAME
    set -q USER_GROUPS || set -l USER_GROUPS ""
    begin
        set -l projectRoot (realpath "$dir/../../..")
        set -l projectName (basename "$projectRoot")
        set -l relativeDir (realpath --relative-to "$projectRoot" "$dir")
        set -l tempRoot "/opt/$(basename "$projectName")"
        set -l tempDir "$tempRoot/$relativeDir"

        loadkeys "$ARCH_KEYMAP"
        and timedatectl set-timezone "$ARCH_TIMEZONE"

        and CONFIG_MODULE=$CONFIG_MODULE bash "$dir/../../Common/OS/partition.sh"

        and pacman-key --init
        and pacman-key --populate

        and pacstrap -K "$ARCH_MOUNT_ROOT" \
            base \
            linux \
            linux-firmware \
            networkmanager \
            man-db \
            man-pages \
            texinfo

        and if type -q installDrivers
            echo "Installing drivers…"
            installDrivers
        else
            true
        end

        and "$dir/../../copy-repo.fish" "$ARCH_MOUNT_ROOT$tempRoot"
        and genfstab -U "$ARCH_MOUNT_ROOT" >> "$ARCH_MOUNT_ROOT/etc/fstab"

        and arch-chroot "$ARCH_MOUNT_ROOT" systemctl enable NetworkManager

        and arch-chroot "$ARCH_MOUNT_ROOT" ln -sf "/usr/share/zoneinfo/$ARCH_TIMEZONE" /etc/localtime
        and arch-chroot "$ARCH_MOUNT_ROOT" hwclock --systohc

        and arch-chroot "$ARCH_MOUNT_ROOT" sed -i "s/^#\?\($LOCALE_PATTERN.*\)\$/\1/" /etc/locale.gen
        and arch-chroot "$ARCH_MOUNT_ROOT" locale-gen

        and begin
            echo "LANG=de_CH.UTF-8"
            echo "LANGUAGE=en_US.UTF-8"
            echo "LC_MESSAGES=en_US.UTF-8"
        end | arch-chroot "$ARCH_MOUNT_ROOT" tee /etc/locale.conf > /dev/null

        and echo "KEYMAP=$ARCH_KEYMAP" | arch-chroot "$ARCH_MOUNT_ROOT" tee /etc/vconsole.conf > /dev/null
        and echo "$ARCH_HOSTNAME" | arch-chroot "$ARCH_MOUNT_ROOT" tee /etc/hostname > /dev/null

        and arch-chroot "$ARCH_MOUNT_ROOT" mkinitcpio -P
        and arch-chroot "$ARCH_MOUNT_ROOT" bash "$tempDir/../Software/GRUB/install.sh"
        and arch-chroot "$ARCH_MOUNT_ROOT" bash "$tempDir/../Software/sudo/install.sh"
        and pacstrap -K "$ARCH_MOUNT_ROOT" git

        and USER_NAME="$USER_NAME" \
        USER_DISPLAYNAME="$USER_DISPLAYNAME" \
        USER_GROUPS="$USER_GROUPS" \
            arch-chroot "$ARCH_MOUNT_ROOT" bash "$tempDir/user.sh"

        and set -l serviceName set-keymap.service
        and set -l serviceFile "$ARCH_MOUNT_ROOT/etc/systemd/system/$serviceName"
        and cp "$dir/$serviceName" "$serviceFile"
        and systemd-nspawn -D "$ARCH_MOUNT_ROOT" systemctl enable "$serviceName"
        and systemd-nspawn -bD "$ARCH_MOUNT_ROOT" -E "ARCH_X11_KEYMAP=$ARCH_X11_KEYMAP"
        and systemd-nspawn -D "$ARCH_MOUNT_ROOT" systemctl disable "$serviceName"
        and rm "$serviceFile"
    end
end